Ir para conteúdo

  • Entrar usando o Facebook Entrar usando o Twitter Entrar usando o Windows Live Login com Steam Login com Google      Entrar   
  • Cadastre-se

Ícone Classificados

Adicionar um Anúncio

Tópicos Recentes

Redes Sociais

Membros mais bem avaliados

Membros VIP mais recentes


Foto
- - - - -

Macro - Retirar nomes dos arquivos dentro de uma pasta

macro extrai arquivos

  • Por favor, faça o login para responder
5 respostas neste tópico

#1 lfsat52

lfsat52
  • Membros Juniores
  • 2 posts
  • Membro desde 07/01/2012
0
Neutra
  • Guarulhos

Postado 07 de janeiro de 2012 - 00h38min

Hello amigos!

preciso de uma força,

Preciso retirar o nome dos arquivos contidos dentro de uma determinada pasta
para facilitar no meu dia-a-dia

algum pode me ajudar?

Gostaria de uma macro em que eu apontando a pasta, ela me retornaria o nome de todos os arquivos contidos nas pastas nas células do excel sem formatação mesmo

valeu


#2 osvaldomp

osvaldomp
  • Membros Plenos
  • 961 posts
  • Membro desde 30/08/2008
302
Excepcional
  • São Paulo - SP

Postado 07 de janeiro de 2012 - 05h42min

1.o código abaixo lista os arquivos de uma pasta e suas sub pastas na Plan1, colocando em 'A' o nome da pasta/sub pasta e em 'B' o nome e a extensão de cada arquivo
2. cole o código em um módulo comum
3. após disparado, o código vai abrir uma caixa de diálogo para que seja selecionada a pasta a pesquisar
4. em seguida abre outra caixa para a escolha do nome e do tipo de arquivo a pesquisar (para listar todos os arquivos da pasta insira curingas nessa caixa *.*, ou para listar arquivos XL 2003 coloque *.xls, ...)
5. em seguida abre outra caixa que permite incluir na pesquisa as sub pastas da pasta escolhida
Sub ListaArquivos()
    Dim myDir As String, temp(), myList, myExtension As String
    Dim SearchSubFolders As Boolean, Rtn As Integer, msg As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show Then
            myDir = .SelectedItems(1)
        End If
    End With
    msg = "nome e extensão do arquivo procurado;" & vbLf & "os curingas abaixo podem ser utilizados" & _
     vbLf & "              * # ?"
    myExtension = Application.InputBox(msg)
    If (myExtension = "False") + (myExtension = "") Then Exit Sub
    Rtn = MsgBox("incluir sub pastas na pesquisa ?", vbYesNo)
    SearchSubFolders = Rtn = 6
    myList = SearchFiles(myDir, myExtension, 0, temp(), SearchSubFolders)
    If Not IsError(myList) Then
        Sheets(1).Cells(1).Resize(UBound(myList, 2), 2).Value = _
        Application.Transpose(myList)
    Else
        MsgBox "não encontrado"
    End If
End Sub
 
 
Private Function SearchFiles(myDir As String _
    , myFileName As String, n As Long, myList() _
    , Optional SearchSub As Boolean = False) As Variant
    Dim fso As Object, myFolder As Object, myFile As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    For Each myFile In fso.getfolder(myDir).Files
        Select Case myFile.Attributes
        Case 2, 4, 6, 34
        Case Else
            If (Not myFile.Name Like "~$*") _
            * (myFile.Path & "\" & myFile.Name <> ThisWorkbook.FullName) _
            * (UCase(myFile.Name) Like UCase(myFileName)) Then
                n = n + 1
                ReDim Preserve myList(1 To 2, 1 To n)
                myList(1, n) = myDir
                myList(2, n) = myFile.Name
            End If
        End Select
    Next
    If SearchSub Then
        For Each myFolder In fso.getfolder(myDir).subfolders
            SearchFiles = SearchFiles(myFolder.Path, myFileName, _
            n, myList, SearchSub)
        Next
    End If
    SearchFiles = IIf(n > 0, myList, CVErr(xlErrRef))
End Function

Osvaldo

#3 chulasantos

chulasantos
  • Membros Juniores
  • 1 posts
  • Membro desde 25/06/2013
0
Neutra
  • Palmela

Postado 25 de junho de 2013 - 20h14min

Obrigado Osvaldomp

No entanto preciso de mais uma ajuda:

- gostava que o codigo me fornecesse só o nome do arquivo sem o caminho (pasta e subpasta)
- gostava ainda de poder colar essa informação numa folha especifica e por exemplo na célula a3 dessa folha.

Pode ajudar-me?
Obrigado


#4 Patropi

Patropi
  • Moderadores
  • 4.234 posts
  • Membro desde 29/11/2009
892
Excepcional
  • Campo Mourão-Pr

Postado 26 de junho de 2013 - 07h50min

Bom dia chulasantos

Seja bem vindo ao fórum!

Baixe o ficheiro e veja se é isto que desejas:

http://www.sendspace.com/file/dy1z02

Dê retorno.

Abraço.

Editado por Patropi, 26 de junho de 2013 - 08h12min.

*Se a resposta foi útil, clique em curtir.
*Se a resposta atendeu, clique em resolvido da resposta que atendeu, para dar o tópico como concluído.

#5 fabio-bitt

fabio-bitt
  • Membros Plenos
  • 264 posts
  • Membro desde 18/06/2009
0
Neutra
  • rio de janeiro

Postado 13 de dezembro de 2013 - 09h30min

Patropi, o Ficheiro já não está mais disponível.

Eu estou com um mesmo problema.

Tenho pastas e sub pastas com PDFs organizadas por anos e meses. E tenho que organizar esses arquivos em uma planilha da seguinte forma:

-Quero que cada palavra do nome do arquivo carregue uma coluna, e que cada arquivo fique em em uma linha.

-As primeiras colunas é sempre um número, gostaria que esse número fosse também um Hyper link para abrir o arquivo pela planilha.

-Algumas informações estão disponíveis apenas dentro do PDF. Posso carregar essas informações também ?

Obrigado a todos.


#6 fabio-bitt

fabio-bitt
  • Membros Plenos
  • 264 posts
  • Membro desde 18/06/2009
0
Neutra
  • rio de janeiro

Postado 13 de dezembro de 2013 - 09h30min

Patropi, o Ficheiro já não está mais disponível.

Eu estou com um mesmo problema.

Tenho pastas e sub pastas com PDFs organizadas por anos e meses. E tenho que organizar esses arquivos em uma planilha da seguinte forma:

-Quero que cada palavra do nome do arquivo carregue uma coluna, e que cada arquivo fique em em uma linha.

-As primeiras colunas é sempre um número, gostaria que esse número fosse também um Hyper link para abrir o arquivo pela planilha.

-Algumas informações estão disponíveis apenas dentro do PDF. Posso carregar essas informações também ?

Obrigado a todos.





0 usuário(s) está(ão) lendo este tópico

0 membros, 0 visitantes, 0 membros anônimos